0104-Objeto Range – Propriedades de L a Q

Como o objeto Range não possui propriedades iniciadas pela letra J, passamos para a série que se inicia com Left e prossegue até QueryTable.

Sub Propriedades_Range_Left()
'Retorna um valor que representa a distância, em pontos, entre o limite
'esquerdo da coluna A e o limite esquerdo do intervalo

'Neste exemplo, é retornada a distância entre as colunas A e a J

MsgBox Range("J1:M10").Left
End Sub
Sub Propriedades_Range_ListHeaderRows()
'Retorna o número de linhas de cabeçalho do intervalo

'É exibida a quantidade de linhas de cabeçalho do intervalo A1:J10
MsgBox Range("A1:J10").ListHeaderRows
End Sub
Sub Propriedades_Range_ListObject()
'Cada objeto ListObject representa uma tabela na planilha

'Neste exemplo, é adicionada uma nova coluna à primeira tabela
'da planilha ativa
Set AddColumn = ListObject(1).ListColumns.Add
End Sub
Sub Propriedades_Range_LocationInTable()
'Retorna uma constante que descreve a parte do relatório de tabela
'dinâmica que contém o canto superior esquerdo do intervalo especificado.
'Pode ser uma das constantes XlLocationInTable a seguir

'|----------------
' xlRowHeader
'|----------------
' xlColumnHeader
'|----------------
' xlPageHeader
'|----------------
' xlDataHeader
'|----------------
' xlRowItem
'|----------------
' xlColumnItem
'|----------------
' xlPageItem
'|----------------
' xlDataItem
'|----------------
' xlTableBody
'|----------------



'Neste exemplo é retornada a localização de D1 em uma tabela dinâmica

Select Case Range("D1").LocationInTable
Case Is = xlRowHeader
    MsgBox "D1 é parte de um cabeçalho de linha"
Case Is = xlColumnHeader
    MsgBox "D1 é parte de um cabeçalho de coluna"
Case Is = xlPageHeader
    MsgBox "D1 é parte de um campo de itens"
Case Is = xlDataHeader
    MsgBox "D1 é parte da área de dados"
Case Is = xlRowItem
    MsgBox "D1 é um item de linha"
Case Is = xlColumnItem
    MsgBox "D1 é um item de coluna"
Case Is = xlPageItem
    MsgBox "D1 é um item de página"
Case Is = xlDataItem
    MsgBox "D1 é um item de dados"
Case Is = xlTableBody
    MsgBox "D1 é um parte do corpo da TD"
End Select

End Sub
Sub Propriedades_Range_Locked()
'Retorna ou define o status do intervalo como bloqueado

'Neste exemplo A1 é definido como bloqueado
Range("A1").Locked = True
End Sub
Sub Propriedades_Range_MDX()
'Retorna o nome do MDX do objeto Range especificado
'MDX = Multidimensional Expression que seria enviado ao provedor
'para preencher o modo de tabela dinâmica

'Retorna o valor do MDX ou exibe uma mensagem de erro
If Range("A1").MDX = "" Then
MsgBox "Esta célula não está conectada a um provedor"
Else
MsgBox Range("A1").MDX
End If
End Sub
Sub Propriedades_Range_MergeArea()
'Retorna o intervalo mesclado que contém a célula especificada

'Neste exemplo é exibido o endereço do intervalo
MsgBox Range("A1").MergeArea.Address
End Sub
Sub Propriedades_Range_MergeCells()
'Retorna verdadeiro se o intervalo fizer parte de um intervalo
'com célula mescladas

'É exibida uma mensagem com base no status de A1
If Range("A1").MergeCells Then
MsgBox "A1 pertence a um intervalo de células mescladas"
Else
MsgBox "A1 não pertence a um intervalo de células mescladas"
End If

End Sub
Sub Propriedades_Range_Next()
'Retorna a próxima célula
'Numa planilha desprotegida retorna a célula à direita
'Numa planilha protegida retorna a próxima célula editável

'Retorna o endereço da próxima célula
MsgBox Range("A1").Next.Address
End Sub
Sub Propriedades_Range_NumberFormat()
'Retorna ou define o código de formatação numérica

'Exemplos de uso, supondo que em A1 tenhamos 40683,50

Range("A1").NumberFormat = "#,###"              'Exibido como 40.684
Range("A1").NumberFormat = "#,###.00"           'Exibido como 40.683,50
Range("A1").NumberFormat = "#,###.##"           'Exibido como 40.683,5
Range("A1").NumberFormat = "dd/mm/yy"           'Exibido como 20/05/11
Range("A1").NumberFormat = "dd/mm/yyyy"         'Exibido como 20/05/2011
Range("A1").NumberFormat = "ddd"                'Exibido como sex
Range("A1").NumberFormat = "dddd"               'Exibido como sexta-feira
Range("A1").NumberFormat = "hh:mm:ss"           'Exibido como 12:00:00
Range("A1").NumberFormat = "[hh]:mm"            'Exibido como sexta 976404:00:00
Range("A1").NumberFormat = "[mm]:ss"            'Exibido como 58584240:00


End Sub
Sub Propriedades_Range_NumberFormatLocal()
'Retorna ou define o código de formatação numérica no idioma do usuário

'Exemplos de uso, supondo que em A1 tenhamos 40683,50
Range("A1").NumberFormatLocal = "#.###"              'Exibido como 40.684
Range("A1").NumberFormatLocal = "#.###,00"           'Exibido como 40.683,50
Range("A1").NumberFormatLocal = "dd/mm/aa"           'Exibido como 20/05/11
Range("A1").NumberFormatLocal = "dd/mm/aaaa"         'Exibido como 20/05/2011

End Sub
Sub Propriedades_Range_Offset()
'Retorna uma célula obtida de um deslocamento a partir de uma
'célula de origem

'Sintaxe: Range.Offset(desloc_lin,desloc_col)
'desloc_lin: deslocamento em linhas. Se positivo indica linhas
'abaixo da referência, se negativo acima da referênia
'desloc_col: deslocamento em colunas. Se positivo indica colunas
'à direita da referência, se negativo à esquerda da referênia


With Range("E10")
    MsgBox .Offset(2, 3).Address        'Exibe $H$12
    MsgBox .Offset(-1, -2).Address      'Exibe $C$9
    MsgBox .Offset(1, -3).Address       'Exibe $B$11
    MsgBox .Offset(-5, 4).Address       'Exibe $I$5
End With

End Sub
Sub Propriedades_Range_Orientation()
'Valor inteiro entre -90 e 90 que define o ângulo de
'inclinação do texto da célula

'Neste exemplo o texto é organizado na vertical ascendentemente
Range("A1").Orientation = 90
End Sub
Sub Propriedades_Range_OutlineLevel()
'Retorna ou define o nível de tópico atual
'da linha ou coluna especificada que faz parte de uma
'estrutura de tópicos

'Neste exemplo é definido o nível 1
Range("A1").OutlineLevel = 1
End Sub
Sub Propriedades_Range_PageBreak()
'Retorna ou define a posição de uma quebra de página.
'Pode ser uma das seguintes constantes XlPageBreak :
'xlPageBreakAutomatic, xlPageBreakManual ou xlPageBreakNone

'Essa propriedade pode retornar posições de quebras de página
'automáticas ou manuais, mas só pode definir posições de quebras
'de página manuais (ela só pode ser definida como
'xlPageBreakManual ou xlPageBreakNone).

'Neste exemplo é forçada uma quebra de página na linha 10
Range("A10").PageBreak = xlPageBreakManual
End Sub
Sub Propriedades_Range_Parent()
'Retorna o objeto ao qual um outro objeto pertence
'No caso de Range, retorna o nome da planilha

MsgBox Range("A1").Parent.Name
End Sub
Sub Propriedades_Range_PivotCell()
'Retorna um objeto PivotCell que representa uma célula em um
'relatório de tabela dinâmica.

'Determinar o nome da tabela dinâmica da qual a célula A1
'faz parte
    MsgBox "A célula A1 está na TD:: " & _
        Application.Range("A1").PivotCell.Parent
End Sub
Sub Propriedades_Range_PivotField()
'Retorna um objeto PivotField que representa o campo de
'tabela dinâmica que contém o canto superior esquerdo do
'intervalo especificado

MsgBox "A célula A1 está no campo:: " & _
        Application.Range("A1").PivotField.Name

Range("A1").PivotField
End Sub
Sub Propriedades_Range_PivotItem()
'Retorna um objeto PivotItem que representa o item de
'tabela dinâmica que contém o canto superior esquerdo
'do intervalo especificado.

MsgBox "A célula A1 está no item:: " & _
        Application.Range("A1").PivotItem.Name

End Sub
Sub Propriedades_Range_PivotTable()
'Retorna um objeto PivotTable que representa o relatório
'de tabela dinâmica que contém o canto superior esquerdo
'do intervalo especificado.

'Este exemplo define a página atual do relatório de tabela
'dinâmica na planilha ativa para ser a página chamada "Brasil".


Set TD = ActiveSheet.Range("A1").PivotTable
TD.PivotFields("País").CurrentPage = "Brasil"

End Sub
Sub Propriedades_Range_Precedents()
'Retorna o intervalo que contém as células
'utilizadas para calcular a célula informada

'Exemplo: são retornados os endereços das células que
'são utilizadas por A1 em seu cálculo ou é
'exibida uma mensagem, caso A1 não utilize outras
'células no cálculo de seu valor

Dim Precedentes As Range

On Error Resume Next
Set Precedentes = Range("A1").Precedents
If Dependentes Is Nothing Then
MsgBox "Esta célula não depende de outras células"
Else
MsgBox "As células " & Precedentes.Address _
& " utilizam o valor de A1"
End If

End Sub
Sub Propriedades_Range_PrefixCharacter()
'Retorna o caractere de prefixo, definido com base
'no alinhamento da célula

'esse caractere será ' para um rótulo justificado à
'esquerda, " para um rótulo justificado à direita,
'^ para um rótulo centrado, \ para um rótulo repetido
'ou em branco

'É exibido o caractere de prefixo da célula A1
MsgBox Range("A1").PrefixCharacter
End Sub
Sub Propriedades_Range_Previous()
'Retorna a célula anterior. Se a planilha estiver desprotegica
'será a célula imediatamente à esquerda. Caso esteja protegida,
'o retorno será a célula desbloqueada imediatamente anterior

'Neste caso, é selecionada a célula anterior a D1
Range("D1").Previous.Select
End Sub
Sub Propriedades_Range_QueryTable()
'Retorna um objeto QueryTable que representa a tabela de consulta
'que intercepta o objeto Range especificado

'Este exemplo atualiza o objeto QueryTable que intercepta a célula
'A1 da planilha ativa
Range("A1").QueryTable.Refresh
End Sub
Anúncios

In Excel We Trust

Marcado com: , , , , , ,
Publicado em Nível: Avançado

Deixe um comentário

Preencha os seus dados abaixo ou clique em um ícone para log in:

Logotipo do WordPress.com

Você está comentando utilizando sua conta WordPress.com. Sair / Alterar )

Imagem do Twitter

Você está comentando utilizando sua conta Twitter. Sair / Alterar )

Foto do Facebook

Você está comentando utilizando sua conta Facebook. Sair / Alterar )

Foto do Google+

Você está comentando utilizando sua conta Google+. Sair / Alterar )

Conectando a %s

Visitas dos usuários
  • 2,069,536

Clique para assinar este blog e receber notificações de novos artigos por email.

Junte-se a 1.534 outros seguidores

Aumente sua interação

Siga-nos do twitter (@usuariosdoexcel).

Acesse o nosso fórum e compartilhe as suas dúvidas.

Curta nossa página no Facebook.

Junte-se ao grupo do LinkedIn.

Visite-nos utilizando o seu smartphone ou tablet.

Recomende este Blog
Visualizar notícias
Site monitorado:
Real Time Web Analytics

Clicky

%d blogueiros gostam disto: