0103-Objeto Range – Propriedades de F a I

Dando continuidade aos nossos exemplos de código utilizando as propriedades do objeto Range, vamos aos objetos de F (Font) a I (Item):

Sub Propriedades_Range_Font()

'A propriedade Font permite realizar alterações na formatação
'da fonte utilizada para um intervalo.
'As alterações são válidas para todo o texto.
'Para acessar partes do texto, verifique a propriedade Characters

'No exemplo a seguir são realizadas uma série de alterações
'na formatação da fonte do intervalo A1

With Range("A1").Font
    .Bold = True                        'Define a fonte em negrito
    .ColorIndex = 3                     'Define a cor da fonte como vermelho
    .FontStyle = "Bold Italic"          'Define o estilo de célula (negrito e itálico)
    .Italic = True                      'Define a fonte em negrito
    .Name = "Arial"                     'Define a fonte como Arial
    .Size = 9                           'Define o tamanho da fonte em 9 pontos
    .Strikethrough = False              'Define que a fonte não será tachada
    .Subscript = False                  'Define que a fonte não será subscrita
    .Superscript = False                'Define que a fonte não será sobrescrita
    .ThemeColor = xlThemeColorAccent1   'Define a cor com base em Ênfase1
    .ThemeFont = xlThemeFontMajor       'Define a fonte primária do tema
    .TintAndShade = 1                   'Define o tom da fonte como escuro
    .Underline = False                  'Define que a fonte não será sublinhada
End With

'Valor possíveis para a propriedade ThemeFont

'--------------------------------------------------------
'Nome                | Descrição
'--------------------------------------------------------
'xlThemeFontMajor    | Principal.
'--------------------------------------------------------
'xlThemeFontMinor    | Secundária.
'--------------------------------------------------------
'xlThemeFontNone     | Não usar qualquer fonte de tema.
'--------------------------------------------------------


End Sub
Sub Propriedades_Range_FormatConditions_Add()

'Retorna os formatos condicionais do intervalo informado
'Veremos a seguir diversas situações de uso, adaptadas do
'help do VBA

'Exemplo: FormatConditions.Add (podem ser adicionadas até
'3 condições) - Incluso na versão 2007 para compatibilidade
'com as versões anteriores
'Sintaxe: FormatConditions.Add(Type, Operator, Formula1, Formula2)

'--------------------------------------------------------------------------------------------------------
'Nome     | Tipo        | Tipo de dados         | Descrição
'--------------------------------------------------------------------------------------------------------
'Type     | Obrigatório | XlFormatConditionType | Especifica se o formato condicional se baseia em um
'         |             |                       | valor de célula ou em uma expressão.
'--------------------------------------------------------------------------------------------------------
'Operator | Opcional    | Variant               | O operador do formato condicional. Pode ser uma
'         |             |                       | destas constantes XlFormatConditionOperator:
'         |             |                       | xlBetween, xlEqual, xlGreater, xlGreaterEqual,
'         |             |                       | xlLess, xlLessEqual, xlNotBetween ou xlNotEqual.
'         |             |                       | Se Type for xlExpression, o argumento Operator será
'         |             |                       | ignorado.
'--------------------------------------------------------------------------------------------------------
'Formula1 | Opcional    | Variant               | A expressão ou o valor associado ao formato condicional.
'         |             |                       | Pode ser um valor de constante, um valor de seqüência
'         |             |                       | de caracteres, uma referência de célula ou uma fórmula.
'--------------------------------------------------------------------------------------------------------
'Formula2 | Opcional    | Variant               | A expressão ou o valor associado à segunda parte do
'         |             |                       | formato condicional quando Operator for xlBetween ou
'         |             |                       | xlNotBetween. Caso contrário, este argumento será
'         |             |                       | ignorado. Pode ser um valor de constante, um valor de
'         |             |                       | seqüência de caracteres, uma referência de célula ou
'         |             |                       | uma fórmula.
'--------------------------------------------------------------------------------------------------------

With Range("A1").FormatConditions _
    .Add(xlCellValue, xlGreater, "=$B$1")
    With .Font
        .Bold = True
        .ColorIndex = 3
    End With
End With


'Propriedades e métodos de FormatCondition

'--------------------------------------------------------------------------------------------------------
'Propriedades   | Descrição
'--------------------------------------------------------------------------------------------------------
'NumberFormat   | Retorna ou define o formato de número aplicado a uma célula caso a regra de formatação
'               | condicional seja avaliada como True.Variant de leitura/gravação.
'--------------------------------------------------------------------------------------------------------
'Priority       | Retorna ou define um valor de prioridade da regra de formatação condicional.
'               | A prioridade determina a ordem da avaliação quando houver várias regras de formatação
'               | condicional em uma planilha.
'--------------------------------------------------------------------------------------------------------
'PTCondition    | Retorna um valor Boolean indicando se o formato condicional está sendo aplicado a um
'               | gráfico PivotTable. Somente leitura.
'--------------------------------------------------------------------------------------------------------
'ScopeType      | Retorna ou define uma das constantes da enumeração XlPivotConditionScope, que determina
'               | a abrangência do formato condicional quando aplicado a um gráfico PivotTable.
'--------------------------------------------------------------------------------------------------------
'StopIfTrue     | Retorna ou define um valor Boolean que determina se as regras de formatação adicionais
'               | na célula devem ser avaliadas se a regra atual avaliar para True.
'--------------------------------------------------------------------------------------------------------
'Text           | Retorna ou define um valor String especificando a seqüência de caracteres de texto
'               | usada pela regra de formatação condicional.
'--------------------------------------------------------------------------------------------------------
'TextOperator   | Retorna ou define uma das constantes da enumeração XlContainsOperator, especificando a
'               | pesquisa de texto realizada pela regra de formatação condicional.
'--------------------------------------------------------------------------------------------------------
'AppliesTo      | Retorna um objeto Range especificando o intervalo de células ao qual a regra de
'               | formatação é aplicada.
'--------------------------------------------------------------------------------------------------------
'DateOperator   | Especifica o operador Date usado na condição de formatação. Leitura/gravação.
'--------------------------------------------------------------------------------------------------------
'FormatRow      | Retorna ou define um valor Boolean especificando se toda a linha da tabela do Excel
'               | deve ser formatada se a regra de formato condicional avaliar para True.
'               | O valor padrão é False.
'--------------------------------------------------------------------------------------------------------

'--------------------------------------------------------------------------------------------------------
'Métodos                | Descrição
'--------------------------------------------------------------------------------------------------------
'ModifyAppliesToRange   | Define o intervalo de células ao qual esta regra de formatação se aplicará.
'--------------------------------------------------------------------------------------------------------
'SetFirstPriority       | Define o valor de prioridade para esta regra de formatação condicional como "1",
'                       | de forma que esta regra seja avaliada antes das outras regras na planilha.
'--------------------------------------------------------------------------------------------------------
'SetLastPriority        | Define a ordem de avaliação para esta regra de formatação condicional, de forma
'                       | que seja avaliada após todas as outras regras da planilha.
'--------------------------------------------------------------------------------------------------------

'Métodos de FormatConditions
'--------------------------------------------------------------------------------------------------------
'Métodos             | Descrição
'--------------------------------------------------------------------------------------------------------
'AddAboveAverage     | Retorna um novo objeto AboveAverage que representa uma regra de formatação
'                    | condicional do intervalo especificado.
'--------------------------------------------------------------------------------------------------------
'AddColorScale       | Retorna um novo objeto ColorScale que representa uma regra de formatação
'                    | condicional que usa gradações em cores de célula para indicar diferenças
'                    | relativas nos valores de células em um intervalo selecionado.
'--------------------------------------------------------------------------------------------------------
'AddDatabar          | Retorna um objeto Databar que representa uma regra de formatação condicional de
'                    | barra de dados do intervalo especificado.
'--------------------------------------------------------------------------------------------------------
'AddIconSetCondition | Retorna um novo objeto IconSetCondition que representa uma regra de formatação
'                    | condicional de um conjunto de ícones do intervalo especificado.
'--------------------------------------------------------------------------------------------------------
'AddTop10            | Retorna um objeto Top10 que representa uma regra de formatação condicional do
'                    | intervalo especificado.
'--------------------------------------------------------------------------------------------------------
'AddUniqueValues     | Retorna um novo objeto UniqueValues que representa uma regra de formatação
'                    | condicional do intervalo especificado.
'--------------------------------------------------------------------------------------------------------

End Sub
Sub Propriedades_Range_FormatConditions_AddAboveAverage()

'Exemplo:    FormatConditions.AddAboveAverage
'Utilização: Destacar valores acima da média

' Preenchendo com dados
    Range("A1") = "Nome"
    Range("B1") = "Número"
    Range("A2").Value = "Exemplo-1"
    Range("A2").AutoFill Destination:=Range("A2:A26"), Type:=xlFillDefault
    Range("B2:B26").FormulaArray = "=INT(RAND()*101)"
    
' Definindo formatação condicional para o intervalo B2:B6.
' As células devem ser destacadas com fonte vermelha e fundo azul
    With Range("B2:B26")
        .FormatConditions.AddAboveAverage
        .FormatConditions(.FormatConditions.Count).SetFirstPriority
        .FormatConditions(1).AboveBelow = xlAboveAverage
        .FormatConditions(1).Font.ColorIndex = 3
        .FormatConditions(1).Interior.ColorIndex = 5
    End With

End Sub
Sub Propriedades_Range_FormatConditions_AddColorScale()
'Exemplo:    FormatConditions.AddColorScale
'Sintaxe:    FormatConditions.AddColorScale(ColorScaleType)
'Utilização: Gradação de cores na célula

'É necessário definirmos.
'1. Se a escala é bicolor ou tricolor (ColorScaleType)
'2. O tipo, o valor e os critérios para os limites de
'cor (ColorScaleCriterion)


'Valores possíveis para ColorScaleType
'ColorScaleType:=2 (Escala bicolor)
'ColorScaleType:=3 (Escala tricolor)


'Depois de definida a escala de cores, é necessário definir os
'os critérios de coloração da célula
'O objeto ColorScaleCriterion especifica o tipo, valor e
'critérios de limite de cor usados na formatação condicional da escala de cores

'Valores possíveis para o tipo (Type)

'-------------------------------------------------------------------------
'Nome                           | Descrição
'-------------------------------------------------------------------------
'xlConditionValueFormula        | Fórmula é usada.
'-------------------------------------------------------------------------
'xlConditionValueHighestValue   | O valor mais alto da lista de valores.
'-------------------------------------------------------------------------
'xlConditionValueLowestValue    | O valor mais baixo da lista de valores.
'-------------------------------------------------------------------------
'xlConditionValueNone           | Sem valor condicional.
'-------------------------------------------------------------------------
'xlConditionValueNumber         | Número é usado.
'-------------------------------------------------------------------------
'xlConditionValuePercent        | Porcentagem é usado.
'-------------------------------------------------------------------------
'xlConditionValuePercentile     | Percentil é usado.
'-------------------------------------------------------------------------

'Você pode definir a cor dos limites mínimo, médio ou máximo para qualquer
'cor usando a propriedade IndexColor

'Definir uma formatação baseada numa escala de cores bicolor com vermelho
'para o valor mínimo e amarelo para a valor máximo, no intervalo A1:A5

With Range("A1:A5")
    'Adicionar uma formatação condicional baseada numa escala bicolor
    .FormatConditions.AddColorScale ColorScaleType:=2
    'Definir a prioridade da aplicação dos critérios
    .FormatConditions(.FormatConditions.Count).SetFirstPriority
    'Definir os parâmetros da formatação inserida
    With .FormatConditions(1)
        'Parâmetros do primeiro critério
        With .ColorScaleCriteria(1)
        'Basear-se no menor valor do intervalo
        .ColorScaleCriteria(1).Type = xlConditionValueLowestValue
        'Definir a cor vermelha
        .ColorScaleCriteria(1).FormatColor.ColorIndex = 3
        End With
        'Parâmetros do segundo critério
        With .ColorScaleCriteria(2)
        'Basear-se no maior valor do intervalo
        .Type = xlConditionValueHighestValue
        'Definir a cor vermelha
        .FormatColor.ColorIndex = 6
        End With
    End With
End With

End Sub
Sub Propriedades_Range_FormatConditions_AddDatabar()
'Exemplo:    FormatConditions.AddDatabar
'Utilização: Barras de dados proporcionais aos valores do intervalo

With Range("A1:A10")
    'Adicionar formatação condicional baseada em barras coloridas
    .FormatConditions.AddDatabar
    'Manter a exibição dos valores numéricos
    .FormatConditions(Selection.FormatConditions.Count).ShowValue = True
    'Definir a prioridade de aplicação da formatação
    .FormatConditions(Selection.FormatConditions.Count).SetFirstPriority
    'Definir os parâmetros para construção das barras
    With .FormatConditions(1)
        'Definir a menor barra com base no valor mínimo
        .MinPoint.Modify newtype:=xlConditionValueLowestValue
        'Definir a maior barra com base no valor máximo
        .MaxPoint.Modify newtype:=xlConditionValueHighestValue
        'Definir a barras na cor azul
        .BarColor.ColorIndex = 5
    End With
End With

End Sub 
Sub Propriedades_Range_FormatConditions_AddIconSetCondition()
'Exemplo:    FormatConditions.AddIconSetCondition
'Utilização: Destacar valores com base num conjunto de ícones

'Valores possíveis para IconSets

'--------------------------------------
'Nome               | Descrição
'--------------------------------------
'xl3Arrows          | 3 Setas
'--------------------------------------
'xl3ArrowsGray      | 3 Setas Cinza
'--------------------------------------
'xl3Flags           | 3 Bandeiras
'--------------------------------------
'xl3Signs           | 3 Sinais
'--------------------------------------
'xl3Symbols         | 3 Símbolos
'--------------------------------------
'xl3TrafficLights1  | Semáforo 1
'--------------------------------------
'xl3TrafficLights2  | Semáforo 2
'--------------------------------------
'xl4Arrows          | 4 Setas
'--------------------------------------
'xl4ArrowsGray      | 4 Setas Cinza
'--------------------------------------
'xl4CRV             | 4 Classificações
'--------------------------------------
'xl4RedToBlack      | Vermelho/Preto
'--------------------------------------
'xl4TrafficLights   | Semáforo (4Cores)
'--------------------------------------
'xl5Arrows          | 5 Setas
'--------------------------------------
'xl5ArrowsGray      | 5 Setas Cinza
'--------------------------------------
'xl5CRV             | 5 Classificações
'--------------------------------------
'xl5Quarters        | Quartos
'--------------------------------------

'Valores possíveis para o tipo (Type)

'-------------------------------------------------------------------------
'Nome                           | Descrição
'-------------------------------------------------------------------------
'xlConditionValueFormula        | Fórmula é usada.
'-------------------------------------------------------------------------
'xlConditionValueHighestValue   | O valor mais alto da lista de valores.
'-------------------------------------------------------------------------
'xlConditionValueLowestValue    | O valor mais baixo da lista de valores.
'-------------------------------------------------------------------------
'xlConditionValueNone           | Sem valor condicional.
'-------------------------------------------------------------------------
'xlConditionValueNumber         | Número é usado.
'-------------------------------------------------------------------------
'xlConditionValuePercent        | Porcentagem é usado.
'-------------------------------------------------------------------------
'xlConditionValuePercentile     | Percentil é usado.
'-------------------------------------------------------------------------

With Range("A1:A10")
'Adicionar formatação condicional baseada num conjunto de ícones
.FormatConditions.AddIconSetCondition
'Definir prioridade de aplicação da formatação
.FormatConditions(.FormatConditions.Count).SetFirstPriority
    'Definir parâmetros da formatação
    With .FormatConditions(1)
        'Manter a ordem crescente
        .ReverseOrder = False
        'Exibir ícones e valores
        .ShowIconOnly = False
        'Definir a exibição de ícones representando quartos
        .IconSet = ActiveWorkbook.IconSets(xl5Quarters)
        
        'Não há necessidade de definições para o primeiro ícone
        
        'Definições para o 2º ícone
        With .IconCriteria(2)
            'Comparação com o valor percentual
            .Type = xlConditionValuePercent
            'Comparação do tipo maior ou igual
            .Operator = xlGreaterEqual
        End With
        
        'Definições para o 3º ícone
        With .IconCriteria(3)
            'Comparação com o valor percentual
            .Type = xlConditionValuePercent
            'Comparação do tipo maior ou igual
            .Operator = xlGreaterEqual
        End With
        
        'Definições para o 4º ícone
        With .IconCriteria(4)
            'Comparação com o valor percentual
            .Type = xlConditionValuePercent
            'Comparação do tipo maior ou igual
            .Operator = xlGreaterEqual
        End With
        
        'Definições para o 5º ícone
        With .IconCriteria(5)
            'Comparação com o valor percentual
            .Type = xlConditionValuePercent
            'Comparação do tipo maior ou igual
            .Operator = xlGreaterEqual
        End With
    End With
End With

End Sub
Sub Propriedades_Range_FormatConditions_AddTop10()
'Exemplo:    FormatConditions.AddTop10
'Utilização: Destacar os dez maiores valores

With Range("A1:A10")
    'Inserir uma formatação condicional destacando os Top10
    .FormatConditions.AddTop10
    'Definir a prioridade de execução da formatação
    .FormatConditions(.FormatConditions.Count).SetFirstPriority
    With .FormatConditions(1)
        'Destacar os maiores valores
        .TopBottom = xlTop10Top 'xlTop10Bottom
        'Número de valores destacados
        .Rank = 10
        'Definir baseado em valores absolutos
        .Percent = False
        'Definir a cor de fonte como preto
        .Font.ColorIndex = 1
        'Definir a cor de preenchimento como amarelo
        .Interior.ColorIndex = 6
        'Não interromper a formatação quando encontrar valores
        .StopIfTrue = False
    End With
End With

End Sub
Sub Propriedades_Range_FormatConditions_AddUniqueValues()
'Exemplo:    FormatConditions.AddUniqueValues
'Utilização: Destacar os valores únicos

With Range("A1:A10")
    'Adicionar formatação condicional baseada em valores únicos
    .FormatConditions.AddUniqueValues
    'Definir a prioridaded de aplicação da formatação
    .FormatConditions(.FormatConditions.Count).SetFirstPriority
    'Definir os parãmetros da formatação condicional
    With .FormatConditions(1)
        'Destacar valores únicos
        .DupeUnique = xlUnique
        'Definir fonte na cor verde
        .Font.ColorIndex = 4
        'Definir preenchimento na cor cinza
        .Interior.ColorIndex = 15
        'Não interromper se for localizado um valor coincidente
        .StopIfTrue = False
    End With
End With

End Sub 
Sub Propriedades_Range_FormatConditions_Delete()
'Exemplo:    FormatConditions.Delete
'Utilização: Remove todos os formatos condicionais

Range("A1").FormatConditions.Delete

End Sub
Sub Propriedades_Range_Formula()

'Utilizado para inserir ou retornar uma fórmula num intervalo.
'Os resultados serão expressos no idioma do VBA (Inglês)

'Neste exemplo, é inserida em A1 a fórmula =SOMA(B1:B10)
Range("A1").Formula = "=SUM(B1:B10)"
End Sub
Sub Propriedades_Range_FormulaArray()

'Retorna ou insere uma fórmula matricial no intervalo.
'O estilo de referência é o R1C1


'No exemplo a seguir é inserida no intervalo A1:A10 a
'fórmula matricial  =SOMA(SE(B1:B10"":B1:B10))
Range("A1:A10").FormulaArray = "=SUM(IF(RC[1]:R[9]C[1]"""",RC[1]:R[9]C[1]))"
End Sub
Sub Propriedades_Range_FormulaHidden()

'Oculta as fórmulas da planilha quando esta é protegida

'No próximo exemplo, as fórmulas do intervalo A1:J100 não
'serão visualizadas na barra de fórmulas quando a planilha
'for protegida
Range("A1:J100").FormulaHidden = True

End Sub
Sub Propriedades_Range_FormulaLocal()

'Retorna ou define a fórmula no idioma do usuário,
'utilizando o estilo de referência A1

'Neste exemplo, é inserida em A1 a fórmula =SOMA(B1:B10)
Range("A1").FormulaLocal = "=SOMA(B1:B10)"
End Sub

Sub Propriedades_Range_FormulaR1C1()

'Retorna ou define a fórmula no idioma do VBA,
'utilizando o estilo de referência R1C1.
'Esta a configuração com que o gravador de macro
'armazena as fórmulas inseridas


'Neste exemplo, é inserida em A1 a fórmula =SOMA(B1:B10)
Range("A1").FormulaR1C1 = "=SUM(RC[1]:R[9]C[1])"
End Sub
Sub Propriedades_Range_FormulaR1C1Local()
'Retorna ou define a fórmula no idioma do usuário,
'utilizando o estilo de referência R1C1.


'Neste exemplo, é inserida em A1 a fórmula =SOMA(B1:B10)
Range("A1").FormulaR1C1Local = "=SOMA(LC[1]:L[9]C[1])"
End Sub
Sub Propriedades_Range_HasArray()
'Retorna True se no intervalo especificado
'está inserida uma fórmula matricial

'O exemplo a seguir exibe uma MsgBox que mostra o status
'de A1

If Range("A1").HasArray Then
MsgBox "Há uma fórmula matricial em A1"
Else
MsgBox "Não há uma fórmula matricial em A1"
End If
End Sub
Sub Propriedades_Range_HasFormula()
'Retorna True se no intervalo especificado
'está inserida uma fórmula

'O exemplo a seguir exibe uma MsgBox que mostra o status
'de A1


If Range("A1").HasFormula Then
MsgBox "Há uma fórmula em A1"
Else
MsgBox "Não há uma fórmula em A1"
End If

End Sub
Sub Propriedades_Range_Height()
'Define/Retorna a altura em pontos do intervalo

'Neste exemplo, é exibida uma mensagem com a altura
'do intervalo A1:A10
MsgBox "O intervalo possui " & Range("A1:A10").Height & _
" pontos de altura"
End Sub
Sub Propriedades_Range_Hidden()
'Retorna ou define se a coluna / linha está oculta ou não

'Neste exemplo a coluna A é oculta
Range("A1").EntireColumn.Hidden = True

'Neste exemplo a linha 10 é oculta
Range("A10").EntireRow.Hidden = True

End Sub
Sub Propriedades_Range_HorizontalAlignment()
'Define ou retorna a forma de alinhamento horizontal
'de texto  para o intervalo


'No exemplo são demonstrados todos os diferentes
'alinhamentos possíveis
With Range("A1")
.HorizontalAlignment = xlCenter             'Centralizado
.HorizontalAlignment = xlDistributed        'Distribuído
.HorizontalAlignment = xlJustify            'Justificado
.HorizontalAlignment = xlLeft               'À esquerda
.HorizontalAlignment = xlRight              'À direita
End With
End Sub
Sub Propriedades_Range_Hyperlinks()
'Retorna um objeto que representa os hyperlinks do intervalo


'Neste exemplo é adicionado um hyperlink em A1
'Anchor: Define o intervalo no qual o hyperlink será inserido
'Address: URL do link
'ScreenTip: Dica de tela exibida quando o ponteiro do mouse está
'sobre a célula que contém o hyperlink
'TextToDisplay: texto a ser inserido na célula
With Range("A1")
    .Hyperlinks.Add _
    Anchor:=.Range("A1"), _
    Address:="https://usuariosdoexcel.wordpress.com/", _
    ScreenTip:="Link para Blog", _
    TextToDisplay:="Usuários do Excel"
End With

'Neste outro exemplo, o hyperlink inserido em A1 é apagado
Range("A1").Hyperlinks.Delete

End Sub
Sub Propriedades_Range_ID()
'Retorna ou define um valor String que representa o rótulo de identificação
'para a célula especificada quando a página é salva como página da Web.

'Neste exemplo é inserido o texto "Valor da célula" e o ID "Rótulo"

Range("A1").Value = "Valor da célula"
Range("A1").ID = "Rótulo"

'Posteriormente, o documento é salvo como página da Web e a linha seguinte
'de HTML é adicionada à página da Web.
'Quando o usuário exibe a página em um navegador da Web e clica no hiperlink,
'o navegador exibe a célula.
'Valor da célula

End Sub
Sub Propriedades_Range_IndentLevel()
'Retorna ou define um valor Variant que representa o nível
'de recuo para a célula ou o intervalo.
'Pode ser um inteiro de 0 a 15.

'Neste exemplo é inserido o texto "Exemplo" na célula A1, e em
'seguida são adicionados 5 recuos.
Range("A1").Valor = "Exemplo"
Range("A1").IndentLevel = 5
End Sub
Sub Propriedades_Range_Interior()
'Retorna o objeto Interior, que corresponde ao pano de fundo
'das células.


'No exemplo a seguir são vistas as diferentes opções
'de uso da formatação do interior do intervalo A1

With Range("A1").Interior
    .Application                           'Retorna "Microsoft Excel"
    .Color = vbRed                         'Formata a cor de preenchimento como vermelha
    .ColorIndex = 3                        'Formata a cor de preenchimento como vermelha
    .Creator                               'Retorna a representação decimal do Excel: 1480803660
    .Gradient                              'Retorna se há ou não gradiente de cor
    .InvertIfNegative = True               'É invertido o padrão de cor se o valor for negativo
    .Parent                                'Retorna o conteúdo da célula
    .Pattern = xlPatternChecker            'Define o padrão de preenchimento (neste caso Xadrez)
    .PatternColor = RGB(255, 0, 0)         'Retorna/define a cor do padrão de preenchimento no padrão RGB (vermelho neste exemplo)
    .PatternColorIndex = 3                 'Retorna/define a cor do padrão de preenchimento com base na paleta de cores
    .PatternThemeColor = 1                 'Retorna/define o tema de cor
    .PatternTintAndShade = 0               'Retorna/define o padrão de tonalidade e sombreamento
    .ThemeColor = xlThemeColorDark2        'Retorna/define a cor do tema no esquema de cores aplicado (Escuro2)
    .TintAndShade = 1                      'Define o tom da cor de preenchimento como escuro
End With


'Valores possíveis para a propriedade Pattern

'--------------------------------------------------------------------------
'Nome                       | Descrição
'--------------------------------------------------------------------------
'xlPatternAutomatic         | O Excel controla o padrão.
'--------------------------------------------------------------------------
'xlPatternChecker           | Tabuleiro de xadrez.
'--------------------------------------------------------------------------
'xlPatternCrissCross        | Linhas de xadrez.
'--------------------------------------------------------------------------
'xlPatternDown              | Linhas diagonais escuras correndo da esquerda
'                           |superior para a direita inferior.
'--------------------------------------------------------------------------
'xlPatternGray16            | 16% cinza.
'--------------------------------------------------------------------------
'xlPatternGray25            | 25% cinza.
'--------------------------------------------------------------------------
'xlPatternGray50            | 50% cinza.
'--------------------------------------------------------------------------
'xlPatternGray75            | 75% cinza.
'--------------------------------------------------------------------------
'xlPatternGray8             | 8% cinza.
'--------------------------------------------------------------------------
'xlPatternGrid              | Grade.
'--------------------------------------------------------------------------
'xlPatternHorizontal        | Linhas horizontais escuras.
'--------------------------------------------------------------------------
'xlPatternLightDown         | Linhas diagonais claras correndo da esquerda
'                           | superior para a direita inferior.
'--------------------------------------------------------------------------
'xlPatternLightHorizontal   | Linhas horizontais claras.
'--------------------------------------------------------------------------
'xlPatternLightUp           | Linhas diagonais claras correndo da esquerda
'                           | inferior para a direita superior.
'--------------------------------------------------------------------------
'xlPatternLightVertical     | Barras verticais claras.
'--------------------------------------------------------------------------
'xlPatternNone              | Sem padrão
'--------------------------------------------------------------------------
'xlPatternSemiGray75        | 75% moiré escuro.
'--------------------------------------------------------------------------
'xlPatternSolid             | Cor sólida.
'--------------------------------------------------------------------------
'xlPatternUp                | Linhas diagonais escuras correndo da esquerda
'                           | inferior para a direita superior.
'--------------------------------------------------------------------------
'xlPatternVertical          | Barras verticais escuras.
'--------------------------------------------------------------------------


'Valores possíveis para a propriedade ThemeColor

'-------------------------------------------------------------------------
'Nome                               | Descrição
'-------------------------------------------------------------------------
'xlThemeColorAccent1                | Ênfase 1
'-------------------------------------------------------------------------
'xlThemeColorAccent2                | Ênfase 2
'-------------------------------------------------------------------------
'xlThemeColorAccent3                | Ênfase 3
'-------------------------------------------------------------------------
'xlThemeColorAccent4                | Ênfase 4
'-------------------------------------------------------------------------
'xlThemeColorAccent5                | Ênfase 5
'-------------------------------------------------------------------------
'xlThemeColorAccent6                | Ênfase 6
'-------------------------------------------------------------------------
'xlThemeColorDark1                  | Escuro 1
'-------------------------------------------------------------------------
'xlThemeColorDark2                  | Escuro 2
'-------------------------------------------------------------------------
'xlThemeColorFollowedHyperlink      | Hiperlink visitado
'-------------------------------------------------------------------------
'xlThemeColorHyperlink              | Hiperlink
'-------------------------------------------------------------------------
'xlThemeColorLight1                 | Claro 1
'-------------------------------------------------------------------------
'xlThemeColorLight2                 | Claro 2
'-------------------------------------------------------------------------

End Sub
Sub Propriedades_Range_Item()
'Retorna o elemento do intervalo cujas coordenadas são especificadas
'Alternativa ao uso de Cells

'No exemplo a seguir é exibido o endereço da célula localizada
'na 3ª linha e na 2ª coluna do intervalo B2:J10 ($C$4)
MsgBox Range("B2:J10").Item(3, 2).Address
End Sub
Anúncios

In Excel We Trust

Marcado com: , , , , , ,
Publicado em Nível: Avançado

Deixe um comentário

Preencha os seus dados abaixo ou clique em um ícone para log in:

Logotipo do WordPress.com

Você está comentando utilizando sua conta WordPress.com. Sair / Alterar )

Imagem do Twitter

Você está comentando utilizando sua conta Twitter. Sair / Alterar )

Foto do Facebook

Você está comentando utilizando sua conta Facebook. Sair / Alterar )

Foto do Google+

Você está comentando utilizando sua conta Google+. Sair / Alterar )

Conectando a %s

%d blogueiros gostam disto: